***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jun 15, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt P4SMAJ6P5CA 1 2 
.param
+vc0 = 2.334e-8		vc1 = 9.227e-8		vc2 = 4.267e-8		vc3 = 1.204
+tc1 = 2.562e-2		tc2 = 8.131e-3		tc3 = 5.222e-3		tc4 = 2.334e-3
d1 1 c zener
g1 c 1 value = {(vc0+vc1*v(c,1)^2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*exp(vc3*v(c,1)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d2 2 c zener
g2 c 2 value = {(vc0+vc1*v(c,2))*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc2*exp(vc3*v(c,2)))*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
.model zener d
***** flag parameter ***
+level = 1   
***** dc model parameter ***
+ is = 1e-12		   n = 1.100		  rs = 1e-3
+ibv = 1e-2			 nbv = 2			  bv = 6.9
***** capacitance parameter ***
+cjo = 1.458e-9		   m = 1.783e-1		  vj = 1.072
+ fc = 0.5                      
***** temperature coefficient ***
+tnom = 25			  eg = 1.100		 xti = 3
+trs1 = 1e-4		tbv1 = 4.408e-4
.ends P4SMAJ6P5CA
*$
